Simple questions
Simple questions¶
These ‘simple questions’ are the example questions available on Cinema Context (with only slight changes to the dates in order to somewhat widen the chronological scope).
Queries¶
Info
It could be that data has been added to the database and that the here presented counts and results therefore do not reflect the current state of the dataset.
1. How many feature films were shown in Utrecht in 1946?¶
Query
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
PREFIX schema: <http://schema.org/>
SELECT (COUNT(?screening) AS ?count) WHERE {
GRAPH <https://data.create.humanities.uva.nl/id/cinemacontext/> {
?place a schema:Place ;
schema:address/schema:addressLocality "Utrecht" .
?theater a schema:MovieTheater ;
schema:location ?place .
?screening a schema:Event ;
schema:location ?theater ;
schema:startDate ?date .
FILTER(YEAR(?date) = 1946)
}
}
Answer: 357
| theaterName | count |
|---|---|
| Palace | 52 |
| Vreeburg Bioscoop | 52 |
| Scala (Potterstraat) | 52 |
| City | 52 |
| Rembrandt | 51 |
| Flora | 51 |
| Olympia | 47 |
2. How many cinemas in Rotterdam screened films in 1931?¶
Query
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
PREFIX schema: <http://schema.org/>
SELECT (COUNT (DISTINCT ?theater) AS ?count) WHERE {
GRAPH <https://data.create.humanities.uva.nl/id/cinemacontext/> {
?place a schema:Place ;
schema:address/schema:addressLocality "Rotterdam" .
?theater a schema:MovieTheater ;
schema:location ?place .
?screening a schema:Event ;
schema:location ?theater ;
schema:startDate ?date .
FILTER(YEAR(?date) = 1931)
}
}
Answer: 19
3. What percentage of Amsterdam cinemas showed French films in 1928?¶
Query
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
PREFIX schema: <http://schema.org/>
SELECT (?french_theaters / ?amsterdam_theaters * 100 AS ?percentage) WHERE {
GRAPH <https://data.create.humanities.uva.nl/id/cinemacontext/> {
{
SELECT (COUNT(DISTINCT ?theater) AS ?amsterdam_theaters) WHERE {
?place a schema:Place ;
schema:address/schema:addressLocality "Amsterdam" .
?theater a schema:MovieTheater ;
schema:location ?place .
}
}
{
SELECT (COUNT(DISTINCT ?theaterFR) AS ?french_theaters) WHERE {
?place a schema:Place ;
schema:address/schema:addressLocality "Amsterdam" .
?theaterFR a schema:MovieTheater ;
schema:location ?place .
?screening a schema:Event ;
schema:location ?theaterFR ;
schema:startDate ?date ;
schema:subEvent [ schema:inLanguage "F" ] .
FILTER(YEAR(?date) = 1928)
}
}
}
}
Answer: 3.33%
4. How many American feature films were banned by the board of censors?¶
For this query, you have to know that wether a film is banned or not is entered in the schema:text property on a schema:Rating. This field can have one of tese values: “toegelaten”, “niet toegelaten”. Keep in mind that we are looking for the number of films, and that a film might have been rated more than once.
Query
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX schema: <http://schema.org/>
SELECT (COUNT(DISTINCT ?film) AS ?count) WHERE {
GRAPH <https://data.create.humanities.uva.nl/id/cinemacontext/> {
?film a schema:Movie ;
schema:countryOfOrigin "USA" ;
schema:contentRating ?rating .
?rating schema:text "niet toegelaten" .
}
}
Answer: 315
5. How many banned films were screened in 1930?¶
A banned film has a rating that contains a schema:text "niet toegelaten" property. The date is attached to the programme, but the film is presented in a sub event of this programme.
Query
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX schema: <http://schema.org/>
SELECT (COUNT(DISTINCT ?film) AS ?count) WHERE {
GRAPH <https://data.create.humanities.uva.nl/id/cinemacontext/> {
?film a schema:Movie ;
schema:contentRating ?rating .
?rating schema:text "niet toegelaten" .
?programme a schema:Event ;
schema:startDate ?date ;
schema:subEvent [ schema:workPresented ?film ]
FILTER(YEAR(?date) = 1930)
}
}
Answer: 38
6. Where in Utrecht could one attend private screenings of the Netherlands Film League (Filmliga)?¶
Names for special film screenings (e.g. children’s matinees, Christmas programme, and also ‘Filmliga’ programmes) are a schema:name property of the schema:Event that denotes a programme.
Query
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
PREFIX schema: <http://schema.org/>
SELECT ?nametheater (COUNT(?theater) AS ?nrofligascreenings) {
GRAPH <https://data.create.humanities.uva.nl/id/cinemacontext/> {
?place a schema:Place ;
schema:address/schema:addressLocality "Utrecht" .
?theater a schema:MovieTheater ;
schema:location ?place ;
schema:name ?nametheater .
?screening a schema:Event ;
schema:location ?theater ;
schema:name ?voorstellingsnaam .
FILTER(CONTAINS(?voorstellingsnaam, "Filmliga"))
# A case insensitive approach would be: FILTER(REGEX(?voorstellingsnaam, "Filmliga", "i"))
}
} GROUP BY ?theater ?nametheater ORDER BY DESC(?nrofligascreenings)
Result:
| nametheater | nrofligascreenings |
|---|---|
| Vreeburg Bioscoop | 42 |
| Rembrandt | 5 |
| Olympia | 1 |
7. When did Dutch music hall and cabaret artist Louis Davids start performing in cinemas? And when did he stop doing this?¶
8. In which cities did the Salvation Army organise film shows in a travelling cinema?¶
9. Which movie theatres were located in Amsterdam?¶
This query retrieves all the known movie theatres located in Amsterdam over the course of the entire period covered by Cinema Context. The results also list the street address and the URI of the cinema.
Query
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
PREFIX schema: <http://schema.org/>
SELECT ?nametheater ?address ?theater
WHERE {
GRAPH <https://data.create.humanities.uva.nl/id/cinemacontext/> {
?place a schema:Place ;
schema:address/schema:addressLocality "Amsterdam" ;
schema:address/schema:streetAddress ?address .
?theater a schema:MovieTheater ;
schema:location ?place ;
schema:name ?nametheater .
}
} GROUP BY ?theater ?nametheater ORDER BY ASC(?nametheater)
Results (Oct 2020)
Last update: May 27, 2021