Workshop 4: Enhanced publications

Introduction

In this workshop we will explore the potantial of Linked Data to create enhanced publications. As a use case we will take the 'Groote schouburgh der Nederlantsche konstschilders en schilderessen' by Arnold Houbraken. This book provides an overview of Netherlandish painters of the sixteenth and seventeenth century. It was originally published in 1718/1721 and is now digitally available at the DBNL. However, the biographies provided by Houbraken are not illustrated and are often erroneous since Houbraken had a greater fondness for anecdote than for accuracy. Linked data sets allow us to create a single screen application in wich a user can simultaneously access the biography by Houbraken, images of artworks by the artists described, and updated biographical information.

De groote schouburgh der Nederlantsche konstschilders en schilderessen

De groote schouburgh der Nederlantsche konstschilders en schilderessen (3 delen). Taken from dbnl.

Data

ECARTICO

ONSTAGE

Schrijverskabinet

Objectives

The group of this workshop consisted of Marten Jan Bok (advisor on the sources); Ivan Kisjes (technical support); Rindert Jagersma, Marissa Griffioen and Julia Noordegraaf (research) In the group we agreed to the following objectives:

  • Create a website with a side-by-side presetation of the biographies of individual artists as discussed in Houbraken (left) and Sandrart (right)

  • Create a website with a presentation of each artist with the Houbraken biography on the left, and on the top right contemporary biographical information on that artist (e.g. from ECARTICO or Wikipedia) and on the top right images of the work of this artist

  • Create a website with a presentation of each artist with the Houbraken biography on the left, above that a portrait of the artist, to the right three layers of images:

    1. top right: images of works mentioned in Sandrart (via Sandrart website), to provide to contemporary perspective of known works;
    2. middle right: RKD images of the work of the artist, to provide the art historically "authorized" perspective;
    3. bottom right: all available images related to the artist on Wikimedia Commons, to provide additional images and images related to the 'Nachleben' of the artist (e.g. a Rhine cruise boat named after the Dutch/German painter Maria Sybilla Merian)

Approach

Ivan Kisjes started to build the website. In the mean time, we worked with the SPARQL queries provided to identify the artists in ECARTICO that are described in Houbraken and in Sandrart. This generated a list of 140 artists, which included a number of double references; in the end there are 133 artists in the ECARTICO database that occur in both Houbraken and Sandrart. We also encountered some female artists, which peaked our interest; we then modified one of the queries to find out which women artists occur in both Houbracken and Sandrart, which turns out to be two: Maria van Oosterwijck and Maria Sybilla Merian. While Ivan was busy, some of the others started to manually identify what information was available in the datasets provided:

  • Vermelding in Sandrart
  • Vergelijken welke actuele info beschikbaar is op ECARTICO
  • Vergelijken welke actuele info beschikbaar is op Wikipedia
  • Onderzoeken welke afbeeldingen van het werk van die kunstenaars beschikbaar zijn in Sandrart (website)/RKD (via de ECARTICO pagina waar een permalink naar de RKD pagina over deze kunstenaar zit)/Wikidata (zie ook link in ECARTICO)/Rijksmuseum (zie identifyers personen uit Wikidata, of https://www.rijksmuseum.nl/nl/zoeken en ook onderstaande queries om matches met Ecartico in beeld te krijgen)

Some findings

Maria Sybilla Merian
Houbraken url
Sandrart url
ECARTICO url
Wikipedia url
Afbeeldingen Sandrart nee
Afbeeldingen Rijksmuseum 7 beschikbaar, waaronder titelpagina insectenboek
Afbeeldingen Wikimedia Commons 654 afbeeldingen beschikbaar; wel ook vervuild met schepen
Afbeeldingen RKD url; 686 afbeeldingen van werken die nu aan haar zijn toegeschreven (link))
Maria van Oosterwyck
Houbraken url
Sandrart url
ECARTICO url
Wikipedia url
Afbeeldingen Sandrart 1, link; deze staat veel groter op Wiki Commons
Wikmedia Commons 43, wel dubbele (link) 1
Afbeeldingen RKD 21, (link))
1. Het lijkt logischer om via haar pagina te zoeken, en dan op paintings by… https://commons.wikimedia.org/wiki/Category:Paintings_by_Maria_van_Oosterwijck

Results

As said above, we identified 133 unique artists mentioned both in Houbraken and Sandrart. This was done by querying both datasets via the ECARTICO dataset, see query below. We then exported the results as a csv file which we inspected via Excel.

The manual analysis of available sources was interesting, in particular because it turns out that Wikimedia Commons has significantly more sources than the RKD Images database, but that these images are not systematically structured so it would require some additional tests to see how best to extract them.

In the end, we manage to realize objective 1: a side-by-side presentation of the Houbraken and Sandrart biographies per artist. See this website: Houbraken-Sandrart Initially, the biographies were not nicely lined up, but Ivan managed to solve that. There is still one issue: the umlaut marks do not translate well to the webpage. We were not able to solve this during the sprint. Nevertheless, we were able to make some comparisons, and found, for example, that Houbraken literally borrowed text from Sandrart for the biography of Jürgen/Jurriaan Ovens. In that sense, the website provides an interesting tool for art historians interested in comparing the historiography on these painters.

Queries

CREATE SPARQL endpoint

# All persons in Ecartico with a link to Wikidata
PREFIX owl: <http://www.w3.org/2002/07/owl#>
PREFIX schema: <http://schema.org/>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
SELECT * WHERE {
  ?ecartico owl:sameAs ?wikidata;
            schema:name ?name.
  FILTER(regex(str(?ecartico), "ecartico" ) ).
  FILTER(regex(str(?wikidata), "wikidata" ) ).
}
# LIMIT 10

All persons in the Panpoeticon with an entry in Ecartico

PREFIX owl: <http://www.w3.org/2002/07/owl#>
PREFIX schema: <http://schema.org/>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
SELECT DISTINCT ?sub ?name ?dbnl ?ecartico ?ename WHERE {
  ?sub rdf:type schema:Person;
       schema:name ?name;
       owl:sameAs ?dbnl.
  ?ecartico owl:sameAs ?dbnl;
            schema:name ?ename.
  FILTER(regex(str(?sub), "https://data.create.humanities.uva.nl/id/schrijverskabinet/" ) ).
  FILTER(regex(str(?dbnl), "dbnl" ) ).
  FILTER(regex(str(?ecartico), "ecartico" ) ).
}
# LIMIT 10

All persons in Ecartico with a reference to Houbraken and optional a reference to sandrart.net

PREFIX schema: <http://schema.org/>
PREFIX owl: <http://www.w3.org/2002/07/owl#>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
SELECT ?ecartico ?name ?vol ?pp ?url ?sandrart WHERE {
  ?sub schema:citation ?node.
  ?node schema:partOf <http://www.vondel.humanities.uva.nl/ecartico/sources/435>;
        schema:url ?url;
        schema:volumeNumber ?vol;
        schema:pagination ?pp.
  ?sub schema:mainEntity ?ecartico.
  ?ecartico schema:name ?name.
  OPTIONAL {
  ?ecartico owl:sameAs ?sandrart.
  FILTER(regex(str(?sandrart), "sandrart.net" ) ).
  }

}
# LIMIT 10

Persons in Rijksmuseum matched against Ecartico

PREFIX owl: <http://www.w3.org/2002/07/owl#>
PREFIX schema: <http://schema.org/>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
SELECT * WHERE {
  ?ecartico owl:sameAs ?wikidata.
  FILTER(regex(str(?ecartico), "RM0001" ) ).
  FILTER(regex(str(?wikidata), "ecartico" ) ).
}
# LIMIT 10

Persons in Rijksmuseum matched against Ecartico, retrieve birthplace from Ecartico

PREFIX owl: <http://www.w3.org/2002/07/owl#>
PREFIX schema: <http://schema.org/>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
SELECT ?rijksmuseum ?ecartico ?name ?placename ?lat ?lon WHERE {
  ?rijksmuseum owl:sameAs ?ecartico.
  ?ecartico schema:name ?name;
            schema:birthPlace ?birthp.
  ?birthp schema:name ?placename;
          schema:geo ?node.
  ?node schema:latitude ?lat;
        schema:longitude ?lon.
  FILTER(regex(str(?rijksmuseum), "RM0001" ) ).
  FILTER(regex(str(?ecartico), "ecartico" ) ).
}
# LIMIT 10

Ecartico vrouwelijke kunstenaars met referenties naar Houbraken:

PREFIX schema: <http://schema.org/>
PREFIX foaf: <http://xmlns.com/foaf/0.1/>
PREFIX owl: <http://www.w3.org/2002/07/owl#>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
SELECT ?ecartico ?name ?gender ?vol ?pp ?url WHERE {
  ?sub schema:citation ?node.
  ?node schema:partOf <http://www.vondel.humanities.uva.nl/ecartico/sources/435>;
        schema:url ?url;
        schema:volumeNumber ?vol;
        schema:pagination ?pp.
  ?sub schema:mainEntity ?ecartico.
  ?ecartico schema:name ?name.
  ?ecartico foaf:gender ?gender .
  FILTER(regex(str(?gender), "Female" ) ).

}
#LIMIT 10

Ecartico vrouwelijke kunstenaars met referenties naar Houbraken en met referentie naar Sandrart

PREFIX schema: <http://schema.org/>
PREFIX foaf: <http://xmlns.com/foaf/0.1/>
PREFIX owl: <http://www.w3.org/2002/07/owl#>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
SELECT ?ecartico ?name ?gender ?vol ?pp ?url ?sandrart WHERE {
  ?sub schema:citation ?node.
  ?node schema:partOf <http://www.vondel.humanities.uva.nl/ecartico/sources/435>;
        schema:url ?url;
        schema:volumeNumber ?vol;
        schema:pagination ?pp.
  ?sub schema:mainEntity ?ecartico.
  ?ecartico schema:name ?name.
  ?ecartico foaf:gender ?gender .
  FILTER(regex(str(?gender), "Female" ) ).
  OPTIONAL {
  ?ecartico owl:sameAs ?sandrart.
  FILTER(regex(str(?sandrart), "sandrart.net" ) ).
  }
}

Ecartico kunstenaars met referenties naar Houbraken én met referentie naar Sandrart

PREFIX schema: <http://schema.org/>
PREFIX foaf: <http://xmlns.com/foaf/0.1/>
PREFIX owl: <http://www.w3.org/2002/07/owl#>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
SELECT ?ecartico ?name ?gender ?vol ?pp ?url ?sandrart WHERE {
  ?sub schema:citation ?node.
  ?node schema:partOf <http://www.vondel.humanities.uva.nl/ecartico/sources/435>;
        schema:url ?url;
        schema:volumeNumber ?vol;
        schema:pagination ?pp.
  ?sub schema:mainEntity ?ecartico.
  ?ecartico schema:name ?name.
  ?ecartico owl:sameAs ?sandrart.
  FILTER(regex(str(?sandrart), "sandrart.net" ) ).
}

results matching ""

    No results matching ""